Tous les serveurs Dell sont fournis avec le logiciel Dell OpenManage Server Administrator qui a la capacité de surveiller et d’afficher les indicateurs de niveau système. En outre, via l’onglet Gestion des alertes, vous pouvez configurer des actions à exécuter chaque fois qu’une alerte est déclenchée. Malheureusement, il n’y a pas de moyen d’appliquer des notifications uniformes à tous les événements, nous allons donc fournir un script qui configure toutes les actions d’alerte pour envoyer un e-mail vous informant de l’événement respectif. Bien que vous puissiez les configurer manuellement, avoir un script est idéal car vous pouvez facilement le déployer sur plusieurs serveurs.
Comment ça fonctionne
Le script est très simple. Il existe une commande de configuration qui définit chaque alerte sur «Exécuter l’application», l’application étant le script lui-même. Lorsque le script s’exécute, il génère simplement un e-mail (en utilisant l’outil Blat) avec le nom de l’ordinateur, la date, l’heure et l’alerte déclenchée.
Avant l’exécution du script:
Après l’exécution du script:
Toutes les alertes utilisent le script de notification par e-mail:
Conditions
Bien entendu, vous devrez installer Dell OpenManage Server Assistant. Ce logiciel, s’il n’est pas fourni avec votre système, peut être téléchargé via le site de support de Dell.
De plus, vous devrez avoir Blat, un emailer en ligne de commande, configuré sur votre système. Pour configurer Blat, téléchargez simplement les fichiers binaires et extrayez-les (3 au total: blat.exe, blat.dll, blat.lib) vers un emplacement dans la variable PATH de votre système, tel que votre dossier Windowssystem32. Puis à partir de la ligne de commande, exécutez:
blat -install my.mailserver.com fromaddress@email.com
Remplacez le serveur de messagerie et l’adresse e-mail de manière appropriée. Pour la plupart, cette commande est tout ce dont vous avez besoin pour exécuter, mais si votre serveur a une configuration spéciale (port alternatif, etc.), vous pouvez voir les options d’installation complètes sur le site Web de Blat.
Configuration de la notification d’alerte par e-mail
Une fois ces exigences en place, vous êtes prêt à utiliser le script. Modifiez le script pour inclure la ou les adresses e-mail à notifier (la variable « ToEmail »). Si votre serveur nécessite une authentification pour relayer, vous devrez ajouter ces paramètres à la commande Blat comme documenté dans le script.
Pour configurer les alertes de l’Assistant du serveur afin d’utiliser le script, exécutez simplement la configuration:
DellAlert / configuration
Confirmez que vous souhaitez utiliser ce script comme action d’alerte et vous êtes prêt. Dans le cadre de la configuration, un exemple d’alerte est déclenché afin que vous puissiez vous assurer que les e-mails atteignent les destinataires prévus.
Le scénario
@ECHO OFF
TITLE Dell Hardware Email Alert
ECHO Dell Hardware Email Alert
ECHO Written by: Jason Faulkner
ECHO SysadminGeek.com
ECHO.
ECHO.
REM Sends email alerts when Dell hardware warnings are triggered.
REM This script should _not_ be in a path which contains spaces.
REM
REM Usage:
REM DellAlert {/SETUP | Alert message}
REM /SETUP Configure Dell Server Assistant to use this script for alerts.
REM Alert Message
REM Message to send.
REM
REM Requires:
REM Blat : (command line emailer) is configured and working on the current system.
REM If your email server requires authentication to relay, see comments below.
REM Email address(es) to send alerts to (comma separated)
SET ToEmail=myaddress@email.com
SETLOCAL EnableExtensions
IF /I {%1}=={/SETUP} GOTO Setup
IF NOT {%1}=={} GOTO Alert
GOTO End
:Alert
SET Log="%TEMP%DellAlert.txt"
DATE /T > %Log%
TIME /T >> %Log%
ECHO Dell Alert Tripped! >> %Log%
ECHO %* >> %Log%
REM If your email server requires autentication to relay,
REM add the following to the end of the line below:
REM -u UserName -pw Password
BLAT %Log% -to %ToEmail% -subject "%ComputerName% Hardware Alert"
IF EXIST %Log% DEL /F /Q %Log%
GOTO End
:Setup
ECHO This will replace all the current Dell Server Assistant alerts with a call
ECHO to this script. To confirm you want to continue, enter YES (case sensitive).
SET /P Confirm=
IF NOT {%Confirm%}=={YES} GOTO End
SET ScriptPath=%~dpnx0
ECHO Configuring alerts to use: %ScriptPath%
omconfig system alertaction event=powersupply execappath="%ScriptPath% power supply failure"
omconfig system alertaction event=powersupplywarn execappath="%ScriptPath% power supply warning"
omconfig system alertaction event=tempwarn execappath="%ScriptPath% temperature warning"
omconfig system alertaction event=tempfail execappath="%ScriptPath% temperature failure"
omconfig system alertaction event=fanwarn execappath="%ScriptPath% fan speed warning"
omconfig system alertaction event=fanfail execappath="%ScriptPath% fan speed failure"
omconfig system alertaction event=voltwarn execappath="%ScriptPath% voltage warning"
omconfig system alertaction event=voltfail execappath="%ScriptPath% voltage failure"
omconfig system alertaction event=intrusion execappath="%ScriptPath% chassis intrusion"
omconfig system alertaction event=redundegrad execappath="%ScriptPath% redundancy degraded"
omconfig system alertaction event=redunlost execappath="%ScriptPath% redundancy lost"
omconfig system alertaction event=memprefail execappath="%ScriptPath% memory pre-failure"
omconfig system alertaction event=memfail execappath="%ScriptPath% memory failure"
omconfig system alertaction event=hardwarelogwarn execappath="%ScriptPath% hardware log warning"
omconfig system alertaction event=hardwarelogfull execappath="%ScriptPath% hardware log full"
omconfig system alertaction event=processorwarn execappath="%ScriptPath% processor warning"
omconfig system alertaction event=processorfail execappath="%ScriptPath% processor failure"
omconfig system alertaction event=watchdogasr execappath="%ScriptPath% watchdog asr"
omconfig system alertaction event=batterywarn execappath="%ScriptPath% battery warning"
omconfig system alertaction event=batteryfail execappath="%ScriptPath% battery failure"
omconfig system alertaction event=systempowerwarn execappath="%ScriptPath% system power warning"
omconfig system alertaction event=systempowerfail execappath="%ScriptPath% system power failure"
omconfig system alertaction event=storagesyswarn execappath="%ScriptPath% storage system warning"
omconfig system alertaction event=storagesysfail execappath="%ScriptPath% storage system failure"
omconfig system alertaction event=storagectrlwarn execappath="%ScriptPath% storage controller warning"
omconfig system alertaction event=storagectrlfail execappath="%ScriptPath% storage controller failure"
omconfig system alertaction event=pdiskwarn execappath="%ScriptPath% physical disk warning"
omconfig system alertaction event=pdiskfail execappath="%ScriptPath% physical disk failure"
omconfig system alertaction event=vdiskwarn execappath="%ScriptPath% virtual disk warning"
omconfig system alertaction event=vdiskfail execappath="%ScriptPath% virtual disk failure"
omconfig system alertaction event=enclosurewarn execappath="%ScriptPath% enclosure warning"
omconfig system alertaction event=enclosurefail execappath="%ScriptPath% enclosure failure"
omconfig system alertaction event=storagectrlbatterywarn execappath="%ScriptPath% storage controller battery warning"
omconfig system alertaction event=storagectrlbatteryfail execappath="%ScriptPath% storage controller battery failure"
ECHO.
ECHO Sending sample alert to:
ECHO %ToEmail%
CALL :Alert Testing Dell hardware alert warnings...
ECHO.
PAUSE
GOTO End
:End
ENDLOCAL
Modifications / Maintenance des scripts
Les alertes d’événement du script fourni proviennent de l’un de nos serveurs Dell. Selon le matériel de votre serveur Dell et la version de Server Assistant, les alertes peuvent varier. En règle générale, vous pouvez savoir lorsque vous exécutez le script de configuration si un événement n’est pas valide pour votre serveur (par exemple, si vous ne disposez pas de contrôleurs Dell RAID) car certains des éléments de création d’événements de stockage échoueront.
Les déclencheurs d’événements dans le script ci-dessus ont été obtenus en exécutant ce qui suit à partir d’une invite de commandes:
alerte système omconfig /?
Cette commande répertorie tous les mots-clés d’événement avec une description de l’alerte respective. Pour ajouter des alertes supplémentaires, exécutez la commande ci-dessus et ajoutez les entrées manquantes à la partie de configuration du script, puis réexécutez le script avec le commutateur / Setup.
Liens
Téléchargez le script d’alerte par e-mail du serveur Dell à partir de SysadminGeek.com
Télécharger Blat Command Line Emailer
