in

Comment utiliser le verrouillage des majuscules comme touche de modification sous Windows

likhit jansawang / Shutterstock.com

La touche de verrouillage des majuscules occupe une place de choix sur le clavier et ne pèse pas sur son poids. Ce script AutoHotkey simple transformera le verrouillage des majuscules en une touche de modification afin que vous puissiez l’utiliser pour des raccourcis personnalisables.

Les bases

Ce script vous permettra d’appuyer sur Caps Lock + G pour rechercher rapidement du texte sur Google depuis n’importe où dans Windows ou d’appuyer sur Caps Lock + D pour rechercher la définition du dictionnaire d’un mot. Ces raccourcis sont bien sûr personnalisables.

Mieux encore, ce script intelligent vous permet toujours d’utiliser le verrouillage des majuscules normalement. Vous pouvez activer et désactiver le verrouillage des majuscules en appuyant rapidement deux fois. Sinon, le verrouillage des majuscules fonctionnera comme une touche de modification pour les raccourcis.

AutoHotkey 101

AutoHotkey est une application Windows gratuite qui se trouve en arrière-plan et exécute des scripts. Vous pouvez écrire vous-même ces scripts ou les télécharger. Les scripts attendent généralement une pression sur une touche et exécutent une action. De cette façon, AutoHotkey est un moyen rapide de remapper des clés dans Windows ou d’attribuer différentes actions aux clés.

Par exemple, nous avons montré comment utiliser AutoHotkey pour désactiver la touche Windows, l’empêchant d’ouvrir le menu Démarrer et vous retirant des jeux PC en plein écran. Pas besoin de soulever le capuchon du clavier.

Installez AutoHotkey et obtenez le script

Télécharger AutoHotkey et installez-le pour commencer. Ensuite, téléchargez le script CapsLock Modifier.

Extrayez le fichier de script AHK du fichier d’archive ZIP et placez-le dans n’importe quel dossier de votre ordinateur. Pour l’exécuter avec AutoHotkey, cliquez avec le bouton droit sur le script et sélectionnez «Exécuter le script».

Exécution d'un script AutoHotkey à partir de l'Explorateur de fichiers.

Le script s’exécute maintenant en arrière-plan. Pour activer et désactiver le verrouillage des majuscules, appuyez deux fois rapidement sur la touche de verrouillage des majuscules.

Si vous ne touchez pas deux fois, le verrouillage des majuscules fonctionne simplement comme une touche de modification. Avec les fonctions intégrées au script, vous pouvez utiliser les raccourcis suivants n’importe où dans Windows:

  • Appuyez sur Verr Maj + d pour trouver la définition du dictionnaire d’un mot sélectionné.
  • Appuyez sur Verr Maj + g pour rechercher sur Google le texte sélectionné n’importe où dans Windows.
  • Appuyez sur Verr Maj + t pour trouver le mot sélectionné dans un dictionnaire des synonymes.
  • Appuyez sur Verr Maj + w pour rechercher le texte sélectionné sur Wikipedia.

Vous voulez plus de raccourcis? Vous pouvez créer le vôtre avec un peu de connaissance des scripts AutoHotkey.

Pour contrôler AutoHotkey, recherchez l’icône AutoHotkey dans votre zone de notification – elle a un fond vert avec un H blanc dessus. Pour arrêter d’exécuter le script, cliquez avec le bouton droit sur l’icône AutoHotkey et sélectionnez «Quitter».

Quitter AutoHotkey et terminer un script.

Comment ça marche?

Si vous souhaitez voir ce que fait le script, cliquez dessus avec le bouton droit de la souris et sélectionnez « Modifier le script » à la place. Cela ouvrira le script dans le Bloc-notes et vous pourrez examiner son code. Le script est assez court et facile à comprendre. Nous vous recommandons de ne pas télécharger et d’exécuter des scripts étranges sans les regarder et les comprendre au préalable.

Ce script nous a été envoyé par Dave Kellog. Voici la partie magique du script qui fait que le verrouillage des majuscules fonctionne comme une touche de modification s’il est enfoncé deux fois:

CapsLock::
KeyWait, CapsLock ; Wait forever until Capslock is released.
KeyWait, CapsLock, D T0.2 ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") ) ; Is a double tap on CapsLock?
{
SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On" ; Toggle the state of CapsLock LED
}
return

Ce bit attend de voir si le verrouillage des majuscules est enfoncé deux fois et active ou désactive le verrouillage des majuscules. Sinon, le script capture le verrouillage des majuscules et l’utilise pour les raccourcis des modificateurs.

Le reste du script contient les actions de raccourci et une fonction de presse-papiers utile qui enregistre le contenu de votre presse-papiers et les restaure. Cette partie est assez nécessaire, car les fonctions de modification utilisent le presse-papiers pour effectuer des actions sur le texte sélectionné.

Vous voulez voir le script complet sans le télécharger? C’est ici:

#NoEnv                      ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn                     ; Enable warnings to assist with detecting common errors.
#SingleInstance FORCE       ; Skip invocation dialog box and silently replace previously executing instance of this script.
SendMode Input              ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.


;================================================================================================
;  CapsLock processing.  Must double tap CapsLock to toggle CapsLock mode on or off.
;================================================================================================
; Must double tap CapsLock to toggle CapsLock mode on or off.
CapsLock::
    KeyWait, CapsLock                                                   ; Wait forever until Capslock is released.
    KeyWait, CapsLock, D T0.2                                           ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
    if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") )                 ; Is a double tap on CapsLock?
        {
        SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On"  ; Toggle the state of CapsLock LED
        }
return



;================================================================================================
; Hot keys with CapsLock modifier.  See https://autohotkey.com/docs/Hotkeys.htm#combo
;================================================================================================
; Get DEFINITION of selected word.    
CapsLock & d::
    ClipboardGet()
    Run, http://www.google.com/search?q=define+%clipboard%     ; Launch with contents of clipboard
    ClipboardRestore()
Return

; GOOGLE the selected text.
CapsLock & g::
    ClipboardGet()
    Run, http://www.google.com/search?q=%clipboard%             ; Launch with contents of clipboard
    ClipboardRestore()
Return

; Do THESAURUS of selected word
CapsLock & t::
    ClipboardGet()
    Run http://www.thesaurus.com/browse/%Clipboard%             ; Launch with contents of clipboard
    ClipboardRestore()
Return

; Do WIKIPEDIA of selected word
CapsLock & w::
    ClipboardGet()
    Run, https://en.wikipedia.org/wiki/%clipboard%              ; Launch with contents of clipboard
    ClipboardRestore()
Return

;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++

;================================================================================================
; Clipboard helper functions.
;================================================================================================
ClipboardGet()
{
    OldClipboard:= ClipboardAll                         ;Save existing clipboard.
    Clipboard:= ""
    Send, ^c                                            ;Copy selected test to clipboard
    ClipWait 0
    If ErrorLevel
        {
        MsgBox, No Text Selected!
        Return
        }
}


ClipboardRestore()
{
    Clipboard:= OldClipboard
}

Nous avons déjà vu des scripts AutoHotkey qui transforment le verrouillage des majuscules en une touche de modification, mais jamais un qui garde le verrouillage des majuscules comme une bascule si vous appuyez deux fois dessus. C’est très intelligent. Merci encore à Dave Kellog de nous l’avoir envoyé.

Laisser un commentaire

Votre adresse e-mail ne sera pas publiée. Les champs obligatoires sont indiqués avec *

Comment empêcher Netflix de lire automatiquement le prochain épisode

Comment empêcher Netflix de lire automatiquement le prochain épisode

Comment faire en sorte que Kodi joue automatiquement le prochain épisode (comme le fait Netflix)